よくつかうコマンドを簡単に実行できるようにするテンプレート。
評価版でよく使うあのコマンドslmgrをバッチで実行できるようにしました。
完全自分用です。
評価版を使ったとき
評価版のWindowsを使ったときによくある話。
Windows評価版には有効期限があって、その有効期限を何回か延長することが可能です。
延長の操作にはslmgrコマンドを利用します。
ですがslmgrにはいくつかオプションがあって、そのオプションをよく忘れる…。
そのため、オプションを覚えるのではなく、バッチファイルでメニューにしたらいいんじゃないか？と思ったのが発端。
バッチファイル
早速バッチファイル。
----------------------------------------------------------------------------------------------
バッチファイル
----------------------------------------------------------------------------------------------
@echo off
:startbatch
set NUM=
set Rtry=
CLS
echo ----------------メニュー----------------
echo [1] ライセンスの猶予期間を確認
echo [2] ライセンス残りのリセット回数確認
echo [3] ライセンス猶予期間のリセット実行
echo [4] この処理を終了する
echo -----------------------------------------
set /p NUM="実行する処理が記載された番号を入力してください >"
if "%NUM%"=="1" goto showLic
if "%NUM%"=="2" goto showreset
if "%NUM%"=="3" goto ResetLic
if "%NUM%"=="4" goto endMsg
goto NoNumber
:showLic
echo .
echo 必要な情報はメモ帳などに転記してください。
echo .
slmgr /dli
pause
goto startbatch
:showreset
echo 必要な情報はメモ帳などに転記してください。
echo .
slmgr /dlv
pause
goto startbatch
:ResetLic
echo --------------------------------------------------
echo 再起動を要求されるためバッチファイルを終了します。
echo --------------------------------------------------
slmgr /rearm
goto endMsg
:NoNumber
echo ちゃんと指定された番号を入力してください。
goto startbatch
:interruption
echo 処理を中断しました。
:end
rem もう一度処理をするかどうか確認し、処理しない場合終了します。
echo --------------------------------------------------------------
echo 別の処理を実行するには[Y]を処理を終了するには[N]を入力し
set /p Rtry="Enterキーを押下します。 >"
if /i %Rtry% == y (goto startbatch)
if /i %Rtry% == n (goto endMsg)
goto endMsg
:endMsg
set NUM=
set Rtry=
echo %0 の動作が完了しました。
------------------------------------------------------------------------------------------------------------
ここまで
------------------------------------------------------------------------------------------------------------
簡単に動作を
実行すると、メニューが表示されます。
[1]でライセンスの猶予期間を確認するコマンド「slmgr /dli」を実行します。これで現状のライセンスの有効期限がどこまでか（今日を過ぎてないか）を確認することができます。
[2]でライセンス残りのリセット回数を確認する「slmgr /dlv」を実行します。これでいま稼働しているWindows評価版のライセンス猶予期間リセットの実行があと何回できるかを確認することができます。
[3]で実際のライセンス猶予期間のリセットを実行する「slmgr /rearm」を実行します。有効期限切れの評価版Windowsはリセット回数の残数が残っているのならば、このリセットによって評価期間の延長ができます。
要するに、ライセンス猶予期間×ライセンスリセット可能回数＝評価版Windowsが利用できる期間、となるのでそれほど時間の掛からないような簡単な評価・検証であればクライアントHyper-V辺りに評価版Windowsをインストールすることによって、その環境を使って（本番環境を構成変更することなく）評価環境が手に入る、というわけです。
